perm filename PAGSER[KA,SYS] blob sn#229757 filedate 1976-08-05 generic text, type C, neo UTF8
COMMENT ⊗   VALID 00011 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	PAGSER - BBN PAGER ROUTINES - JBR 4/75 	ZSGMAP, ASGMAP
C00007 00003	ZERPR2, UPMAPL, LMAPL, STRMAP
C00015 00004	UNPMAP, MAKMAP, ZAPLOW, ZAPLOJ, AUPMAP
C00019 00005	P2GTRP
C00028 00006	KLPFTR - KL10 PAGE TRAPS
C00036 00007	KL10 AR/ARX PARITY ERROR PAGE FAULTS
C00038 00008	PAGSET, PAGSEN, PAGSE1, P2GSE1
C00041 00009	ADPEMP, ADDEMP, DELEMP, ADDEVP
C00046 00010	PAGINI - INITIALIZE THE EXEC PAGE TABLE, PSB, AND WHATNOT
C00048 00011	MAPSET, APRMAP, POPMAP, ACTOSH, SHTOAC, PSHMAP
C00056 ENDMK
C⊗;
SUBTTL PAGSER - BBN PAGER ROUTINES - JBR 4/75 	;ZSGMAP, ASGMAP

IFN FTPAGER,<		;THIS ENTIRE FILE IS UNDER THE FTPAGER CONDITIONAL

LOSYS			;FOR SANITY, THIS RUNS IN LOWCORE


;ROUTINE TO FLUSH A SEGMENT FROM THE PAGE MAP OF THE LOWER
;CALL WITH JOB NUMBER OF THE LOWER IN TAC, OF THE UPPER IN J.

↑ZSGMAP:PUSH	P,TAC1
	MOVE	TAC1,JBTMAP(TAC)	;GET POINTER TO PAGE MAP OF LOWER
	LSH	TAC1,=9
	CAMGE	TAC1,MEMSIZ		;MUST BE INSIDE FREE STORAGE
	JRST	NOJMAP
	PUSH	P,AC1
	PUSH	P,AC2
	HLRZ	AC1,JBTPAG(J)		;NUMBER OF PAGES IN SEGMENT
	JUMPE	AC1,ZSGMA1		;JUMP IF THE SEGMENT IS SWAPPED OUT
ZSGMA2:	HLRZ	AC2,JBTPAG(TAC)		;NUMBER OF PAGES IN THE LOWER
	CAIGE	AC2,400
	MOVEI	AC2,400			;PAGE NUMBER WHERE UPPER STARTS
	ADDI	AC2,(TAC1)		;ADDRESS OF MAP ENTRY FOR UPPER'S FIRST PAGE
	SETZM	(AC2)			;FLUSH PAGE MAP ENTRY FOR UPPER'S FIRST PAGE
	HRLI	AC2,(AC2)		;BLT POINTER.  (DESTINATION IS WRONG)
	ADDI	AC1,(AC2)		;AC1←ADDR. OF UPPER'S LAST MAP ENTRY+1
	ADDI	AC2,1			;SOURCE,,DESTINATION
	BLT	AC2,-1(AC1)		;ZERO PAGE MAP ENTRIES FOR UPPER.
ZSGMAX:	POP P,AC2
	POP P,AC1
	POP P,TAC1
	POPJ P,

ZSGMA1:	MOVSI	AC1,SWP
	TDNN	AC1,JBTSTS(J)	;SKIP IF SEG REALLY SWAPPED OUT
	JRST	ZSGMAX		;NON-EX SEGMENT (IT CAN HAPPEN)
	MOVE	TAC1,J
	PUSHJ	P,CORSGT	;GET SIZE OF UPPER (IN WORDS, IN TAC1)
	LSH	TAC1,-=9
	MOVE	AC1,TAC1
	JRST	ZSGMA2

NOJMP1:	POP P,AC3
	POP P,AC2
	POP P,AC1
NOJMAP:	POP P,TAC1
	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /JBTMAP CLOBBERED AT ZSGMAP OR ASGMAP.
/
	PUSHJ P,DISFLU
	PUSHJ P,WDDTCA
	POPACS
	POPJ P,

;ROUTINE TO ADD A SEGMENT TO THE PAGE MAP OF THE LOWER
;CALL WITH JOB NUMBER OF THE LOWER IN TAC, OF THE UPPER IN J.

↑ASGMAP:PUSH P,TAC1
	PUSH P,AC1
	PUSH P,AC2
	PUSH P,AC3
	HLRZ	AC3,JBTPAG(J)		;NUMBER OF PAGES IN THE UPPER
	JUMPE	AC3,ASGMAX		;JUMP IF UPPER ISN'T IN CORE.
	SKIPE	TAC1,JBTMAP(J)		;TAC1←JBTMAP OF UPPER
	SKIPN	AC1,JBTMAP(TAC)		;AC1←JBTMAP OF LOWER
	JRST	NOJMP1			;SOMEONE'S JBTMAP IS LOSING
	LSH	TAC1,=9
	LSH	AC1,=9
	CAML	TAC1,MEMSIZ
	CAMGE	AC1,MEMSIZ
	JRST	NOJMP1			;MAPS MUST LIVE IN FREE STORAGE
	HLRZ	AC2,JBTPAG(TAC)		;NUMBER OF PAGES IN THE LOWER
	CAIGE	AC2,400
	MOVEI	AC2,400			;AC2←STARING PAGE OF THE UPPER.
	ADDI	AC2,(AC1)		;SETUP TO BLT JBTMAP(UPPER) TO
	HRLI	AC2,(TAC1)		; JBTMAP(LOWER) WHERE UPPER BEGINS
	ADDI	AC3,(AC2)		;ADDRESS OF FIRST PAGE PAST LAST ONE
	BLT	AC2,-1(AC3)		;COPY JBTMAP ENTRIES FROM THE UPPER TO LOWER
	CAIGE	AC3,1000(AC1)		;SKIP IF PAGE 777 WAS FILLED.
	SKIPN	(AC3)			;DID THE UPPER SHRINK?
	JRST	ASGMAX			;SEEMINGLY NOT.
	SETZM	(AC3)			;ZERO EXTRA ENTRIES IN JBTMAP OF LOWER
	CAIL	AC3,777(AC1)		;VERY LAST PAGE?
	JRST	ASGMAX			;YES. AVOID THE BLT.
	HRLI	AC3,(AC3)
	ADDI	AC3,1
	BLT	AC3,777(AC1)
ASGMAX:	POP	P,AC3
	POP	P,AC2
	POP	P,AC1
	POP	P,TAC1
	POPJ	P,
;ZERPR2, UPMAPL, LMAPL, STRMAP

;ROUTINE TO ZERO JBTPR2 AND CLEAR THE CORRESPONDING PAGE MAP
;ENTRIES FOR THE UPPER.  SKIPS IF THERE WAS NO JBTPR2.

↑ZERPR2:SKIPN JBTPR2(J)
	JRST CPOPJ1
	PUSHJ P,UPMAPL		;LOOP THROUGH UPPER PAGE MAP ENTRIES
	 SETZM (TAC1)		; ZEROING EACH ONE
	SETZM JBTPR2(J)
	POPJ P,

;ROUTINE TO LOOP THROUGH ALL PAGE MAP LOCATIONS CORRESPONDING TO THE UPPER
;SEGMENT ACCORDING TO JBTPR2.  IT WILL EXECUTE THE INSTRUCTION AFTER THE
;PUSHJ P,UPMAPL.  TAC1 WILL BE THE ADDRESS OF THE PAGE TABLE ENTRY.  AC2
;WILL HAVE THE CORRECT PAGE TABLE ENTRY TO STORE FOR A SIMPLE SETPR2.
;AC1 WILL HAVE A COPY OF JBTPR2(LOWER), J SHOULD HAVE THE JOB NUMBER OF
;THE LOWER

↑UPMAPL:PUSH	P,TAC
	PUSH	P,TAC1
	PUSH	P,AC1
	PUSH	P,AC2
	MOVE	TAC,JBTPR2(J)
	MOVE	TAC1,JBTMAP(J)	;POINTER TO PAGE MAP
	LSH	TAC1,=9
	TRNE	TAC,4		;IS THIS THE GETHI HACK?
	JRST	UPMPGH		;YES.  DO GETHI
	TRNE	TAC,1		;ABSOLUTE RELOC?
	JRST	UPMAP2		;YES.
UPMAP1:	LDB	AC2,[POINT 9,TAC,26]	;GET RELOC OF UPPER AS A PAGE NUMBER
	TLO	AC2,120040		;SET READ, EXECUTE, AND ACCESS
	TLNN	TAC,1			;SKIP IF WRITE PROTECTED
	TLO	AC2,40000		;TURN ON WRITE ENABLE BIT
	HLRZ	AC1,JBTPAG(J)		;NUMBER OF PAGES IN THE LOWER
	CAIGE	AC1,400
	MOVEI	AC1,400		;AC1←FIRST VIRTUAL PAGE NUMBER FOR UPPER.
	ADDI	TAC1,(AC1)	;CORRESPONDING PAGE MAP ADDRESS
	HLRZ	TAC,TAC		;PROTECTION OF THE UPPER
	IORI	TAC,401777
	LSH	TAC,-9		;LAST PAGE NUMBER OF UPPER
	SUBI	TAC,-1(AC1)	;NUMBER OF PAGES OF UPPER
UPMAP4:	MOVE AC1,JBTPR2(J)
UPMAP3:	XCT @-4(P)		;EXECUTE ARGUMENT
	ADDI AC2,1		;BUMP PAGE TABLE ENTRY
	ADDI TAC1,1		;BUMP PAGE TABLE ADDRESS
	SOJG TAC,UPMAP3		;COUNT DOWN NUMBER OF PAGES
UPMAPX:	POP P,AC2
	POP P,AC1
	POP P,TAC1
	POP P,TAC
	JRST CPOPJ1

UPMPGH:	LDB	AC2,[POINT 13,TAC,30]	;GETHI HACK.  GET STARTING PAGE NUMBER.
	HRLI	AC2,120040		;READ, EXECUTE AND ACCESS PERMISSION.
	TRNE	TAC,20			;USER WANTS TO WRITE?
	TLO	AC2,040000		;YES. SET WRITE PERMISSION
	HLRZ	TAC,TAC			;NUMBER OF PAGES TO ADD TO MAP.
	ADDI	TAC1,400		;START AT VIRTUAL PAGE 400.
	JRST	UPMAP4

UPMAP2:	HLRZ	AC1,JBTPAG(J)	;NUMBER OF PAGES IN THE LOWER
	LSH	AC1,=9
	SUBI	AC1,1		;LOWER'S PROTECTION
	SUBI	AC1,(TAC)	;COMPUTE ROOM FROM START OF UPPER TO TOP OF LOWER
	JUMPL	AC1,UPMAPX	;UPPER TRYING TO START ABOVE TOP OF LOWER
	HLRZ AC2,TAC		;REQUESTED UPPER SIZE (WITH WR PROT BIT)
	CAILE AC2,(AC1)		;GET MIN OF REQUESTED SIZE AND ROOM
	MOVEI AC2,(AC1)
	ANDCMI AC2,1		;TURN OFF WRITE PROT BIT
	TLNE TAC,1		;SKIP IF ORIGINAL WR PROT BIT IS OFF
	IORI AC2,1		;TURN IT BACK ON
	HRLI TAC,(AC2)		;NEW UPPER PROTECTION
	HRRZ	AC1,JBTPAG(J)	;FIRST PAGE OF LOWER
	LSH	AC1,=9		;RELOC OF LOWER
	ADDI	TAC,(AC1)
	JRST	UPMAP1

;LOOP THROUGH ALL PAGE MAP LOCATIONS CORRESPONDING TO THE LOWER
;ACCORDING TO AC1,,DSER.  IT WILL EXECUTE THE INSTRUCTION AFTER THE
;PUSHJ P,LMAPL.  TAC1 WILL BE THE ADDRESS OF THE PAGE TABLE ENTRY.  AC2
;WILL HAVE THE CORRECT PAGE TABLE ENTRY TO STORE.  J SHOULD HAVE THE JOB
;NUMBER OF THE LOWER
;
;CALL:	MOVE	AC1,<NUMBER OF PAGES>
;	MOVE	DSER,<FIRST PAGE>
;	MOVE	J,<JOB NUMBER OF LOWER>
;	PUSHJ	P,LMAPL
;	 <INSTR TO XCT FOR EACH PAGE>	;TAC1=ADDRESS OF PAGE TABLE ENTRY
;					;AC2=PAGE TABLE ENTRY TO STORE

↑LMAPL:	PUSH	P,TAC
	PUSH	P,TAC1
	MOVE	TAC1,JBTMAP(J)	;ADDRESS OF PAGE MAP
	LSH	TAC1,=9
	CAIL	DSER,1000		;BUG TRAP FOR HI-CORE SEGMENTS
	PUSHJ	P,LMBUG

LMAP2:	PUSH	P,AC2
	MOVE	AC2,DSER		;AC2←FIRST PAGE
	HRLI	AC2,160040		;SET UP PAGE TABLE ENTRY
	MOVE	TAC,AC1			;NUMBER OF PAGES
LMAP1:	XCT	@-3(P)
	ADDI	AC2,1			;BUMP PAGE TABLE ENTRY
	ADDI	TAC1,1			;BUMP PAGE TABLE ADDRESS
	SOJG	TAC,LMAP1		;LOOP FOR ALL LOWER PAGES
	POP	P,AC2
	POP	P,TAC1
	POP	P,TAC
	JRST	CPOPJ1

LMBUG:	PUSHACS
	PUSHJ	P,DISJOB
	PUSHJ	P,DISMES
	ASCIZ	/ HI-CORE USER AT LMAPL.  PROCEDE AT YOUR OWN PERIL
/
	PUSHJ	P,DISFLU
	PUSHJ	P,DDTCALL
	POPJ	P,


;ZERO PAGE MAP ENTRIES FOR A JOB THAT IS SHRINKING
;CALL:	MOVE	AC1,<NUMBER OF PAGES TO ZERO>
;	MOVE	J,<JOB NUMBER OF LOWER>
;	MOVE	TAC,<NUMBER OF PAGES TO KEEP IN THE LOWER>
;	PUSHJ	P,ZMAPL
;	 SETZM (TAC1)

↑ZMAPL:	PUSH	P,TAC
	PUSH	P,TAC1
	MOVE	TAC1,JBTMAP(J)
	LSH	TAC1,=9
	ADDI	TAC1,(TAC)		;START AFTER LOWER
	JRST	LMAP2

;ROUTINE TO STORE PAGE MAP ENTRIES, SETTING WRITE PROTECTION IF DDB IS NON-ZERO
;USED AS ARGUMENT TO PUSHJ P,LMAPL

↑STRMAP:SKIPE DDB
	TLZ AC2,40000		;TURN OFF WRITE PERMISSION
	MOVEM AC2,(TAC1)	;AND STORE PAGE MAP ENTRY
	POPJ P,

;SET OR CLEAR WRITE PROTECT BIT IN ALL PAGES OF A JOB.
;CALL WITH J=JOB NUMBER, DDB=0 FOR WRITE PERMIT

↑WPMAPL:MOVE	TAC1,JBTMAP(J)
	LSH	TAC1,=9
	JUMPE	TAC1,CPOPJ
	HRLI	TAC1,-1000
WPMAP1:	SKIPN	AC2,(TAC1)
	JRST	WPMAP2
	HRLI	AC2,160040
	PUSHJ	P,STRMAP
WPMAP2:	AOBJN	TAC1,WPMAP1
	POPJ	P,
;UNPMAP, MAKMAP, ZAPLOW, ZAPLOJ, AUPMAP

;UNPURIFY AN UPPER SEGMENT AND ALL THE LOWERS THAT ARE IN CORE
;AND POINT TO IT.  AC1 HAS JOB NUMBER OF THE UPPER

↑UNPMAP:PUSH P,DSER
	PUSH P,AC1
	PUSH P,TAC
	PUSH P,J
	MOVE J,AC1		;SET UP JOB NUMBER OF UPPER
	HLRZ	AC1,JBTPAG(J)	;PROT OF UPPER
	HRRZ	DSER,JBTPAG(J)	;REL OF UPPER
	PUSHJ	P,LMAPL		;LOOP THROUGH PAGES OF UPPER
	 MOVEM	AC2,(TAC1)	; STORING ENTRIES WITH WRITE ENABLED
	PUSHJ P,AUPMAP		;NOW SPEAD THIS THROUGH ALL OUR LOWERS IN CORE
	POP P,J
	POP P,TAC
	POP P,AC1
	POP P,DSER
	POPJ P,

;ROUTINE TO SET UP JBTMAP(J) TO NEW PAGE MAP UNLESS IT ALREADY HAS ONE

↑MAKMAP:PUSH	P,AC1
	SKIPE	AC1,JBTMAP(J)
	JRST	MAKMP1
	PUSHJ	P,GETMAP
	HALT	.		;GETMAP ALWAYS SKIPS AT UUO LEVEL
MAKMP1:	MOVEM	AC1,JBTMAP(J)
	POP	P,AC1
	POPJ	P,

;ROUTINE TO REMOVE AN UPPER FROM ALL ITS LOWER'S MAPS
;JOB NUMBER OF THE UPPER IS IN AC1

↑ZAPLOW:PUSH P,J
	MOVE J,AC1
	PUSHJ P,ZAPLOJ
	POP P,J
	POPJ P,

↑ZAPLOJ:PUSH P,TAC
	PUSHJ P,UAPPLY
	 PUSHJ P,ZAPLO1		;ROUTINE TO CALL FOR EACH LOWER OF THE UPPER
	POP P,TAC
	POPJ P,

;GET HERE FOR EACH LOWER OF THE UPPER, WITH JOB NUMBER OF LOWER IN J
;JOB NUMBER OF UPPER IN DDB

ZAPLO1:	SKIPE	JBTMAP(J)	;SKIP IF THERE'S NO MAP
	SKIPN	JBTPAG(J)	;SKIP IF LOWER'S INCORE
	POPJ	P,
	MOVE	TAC,J		;LOWER IN TAC
	MOVE	J,DDB		;UPPER IN J
	PUSHJ	P,ZSGMAP	;FLUSH UPPER PAGES FROM LOWER'S MAP
	MOVE	J,TAC
	POPJ	P,

;SPREAD AN UPPER TO THE PAGE MAP OF EACH OF ITS LOWERS. CALL WITH J = UPPER'S NUMBER

↑AUPMAP:PUSH P,TAC
	PUSHJ P,UAPPLY
	 PUSHJ P,AUPMA1		;ROUTINE TO CALL FOR EACH LOWER OF THE UPPER
	POP P,TAC
	POPJ P,

;GET HERE FOR EACH LOWER OF THE UPPER, WITH JOB NUMBR OF LOWER IN J
;JOB NUMBER OF UPPER IN DDB

AUPMA1:	SKIPE	JBTMAP(J)	;DO NOTHING UNLESS LOWER HAS A MAP
	SKIPN	JBTPAG(J)	;AND CORE ASSIGNED IN CORE
	POPJ	P,
	MOVE	TAC,J		;TAC←JOB NUMBER OF LOWER
	MOVE	J,DDB		;J←JOB NUMBER OF UPPER
	PUSHJ	P,ASGMAP	;
	MOVE	J,TAC
	POPJ	P,
;P2GTRP

↑P2GTRP:EXCH P,P2GPDL
	PUSH P,TAC
	MOVE TAC,PSB+TSW	;GET TRAP STATUS WORD
	TLNE TAC,400		;PARITY ERROR?
	JRST P2GPAR
	TLNE TAC,100		;KEY CYCLE
	JRST P2GKEY
	CONSZ PI,77400		;SKIP IF NOT IN PROGRESS
	JRST P2GBCH		;BAD TO PAGE FAULT IN PROGRESS ON P2

IFN FTMAPBUG,<
	PUSH P,TAC1
	LDB TAC,[POINT 6,P2PAG1,35]	;JOB NUMBER THAT MAP IS SETUP FOR
	JUMPE TAC,P2GTOK		;NULL JOB IS OK.
	HLRZ TAC1,P2PAG			;PAGER'S UBR
	CAMN TAC1,JBTMAP(TAC)		;OUGHT TO BE THE SAME.
	JRST P2GTOK			;YES.  LEAVE.
PGTLOS:	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /PAGE TRAP WITH PAGREG INCONSISTENT.
P2PAG = /
	MOVE TAC,P2PAG
	PUSHJ P,DISOCT
	PUSHJ P,DISMES
	ASCIZ /
P2PAG1 = /
	MOVE TAC,P2PAG1
	PUSHJ P,DISOCT
	PUSHJ P,DISMES
	ASCIZ /
JBTMAP(P2PAG1[30:35]) = /
	LDB TAC,[POINT 6,P2PAG1,35]
	MOVE TAC,JBTMAP(TAC)
	PUSHJ P,DISOCT
	PUSHJ P,DISCRLF
	POPACS
P2GTOK:	POP P,TAC1
	MOVE TAC,PSB+TSW
>;FTMAPBUG

	TLNE TAC,240		;NXM OR PI CYCLE?
	JRST P2GBAD		;SOMETHING BAD HAPPENED
	CAMGE TAC,[600000,,000000]
	TLNE TAC,160000
	JRST P2GBAD		;TSR 0,1 ≠ 1 0 OR BAD TRAP
	TLNE TAC,1000		;ADRESS LIMIT REGISTER VIOLATION?
	JRST P2GADL		;YES
	TLNN TAC,16000		;NO ACCESS OR ILLEGAL READ/EXECUTE OR WRITE
	JRST P2GBAD		;NO
	MOVE TAC,P2GINT		;GET TRAP PC.
	TLNN TAC,USRMOD		;USER MODE?
	CONSO PI,77400		;EXEC MODE.  UUO LEVEL?
	JRST .+2		;USER MODE OR UUO LEVEL TRAP.
	JRST P2GEMD		;EXEC MODE PI IN PROGRESS.  WORRY!
	POP P,TAC
	EXCH P,P2GPDL
	CONO PI,APROFF		;DON'T GET INTO CH3 WITH PAGFLG BUT NO ILM
	SETOM P2GFLG		;TELL CHANNEL 3 WE'RE COMING
	CONO PI,20000		;SET CPA MEM PROT FLAG
	CONO PI,APRON
	JFCL
	JRST 4,.		;I CAN'T WAIT FOREVER, YOU KNOW!

P2GPAR:	PUSHACS
	CONI PI,TAC
	CONO PI,PIOFF
	CONO PAG,4		;TURN OFF ALL MAPPING
	PUSH P,TAC
	PUSHJ P,DISMES
	ASCIZ /PAGER PARITY ERROR
/
P2GPAX:	PUSHJ P,DISMES
	ASCIZ /TSW = /
	MOVE TAC,PSB+TSW
	PUSHJ P,DISOCT
	PUSHJ P,DISMES
	ASCIZ /    P2GINT = /
	MOVE TAC,P2GINT
	PUSHJ P,DISOCT
	PUSHJ P,DISCRLF
	PUSHJ P,DISFLU
	PUSHJ P,DDTCAL
	CONO PAG,0		;LOAD UP REGISTERS AGAIN
	CONO PAG,7		;TURN MAPPING BACK ON (MAP ALL OF EXEC)
	POP P,TAC
	TRNE TAC,200		;SKIP IF PIS WERE OFF
	CONO PI,PION
	POPACS
	POP P,TAC
	EXCH P,P2GPDL
	JRST 2,@P2GINT

P2GKEY:	PUSHACS
	CONI PI,TAC
	CONO PI,PIOFF
	CONO PAG,4		;TURN OFF MAPPING
	PUSH P,TAC
	PUSHJ P,DISMES
	ASCIZ /PAGE FAULT ON KEY CYCLE
/
	JRST P2GPAX

;THIS IS SOMETHING TO CONSIDER LATER.
P2GEMD:	POP P,TAC
	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /PAGE FAULT - NO ACCESS OR ILLEGAL ACCESS - PI IN PROGRESS
PI = /
	JRST P2GBC0

;EXEC MODE AND PI IN PROGRESS.
P2GBCH:	POP P,TAC
	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /PAGE FAULT PI IN PROGRESS PI = /
P2GBC0:	CONI PI,TAC
	PUSHJ P,DISLOC
P2GBC1:	PUSHJ P,DISMES
	ASCIZ /  PC = /
	MOVE TAC,P2GINT
	PUSHJ P,DISOCT
	PUSHJ P,DISMES
	ASCIZ /
TRAP STATUS = /
	MOVE TAC,PSB+TSW
	PUSHJ P,DISOCT
	PUSHJ P,DISMES
	ASCIZ /
WILL DISMISS VIA JRST 2,@P2GINT
/
	PUSHJ P,DISFLU
	PUSHJ P,WDDTCA
	POPACS
	EXCH P,P2GPDL
	JRST 2,@P2GINT

P2GBAD:	POP P,TAC
	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /PAGE FAULT WITH BAD TRAP STATUS/
	JRST P2GBC1

P2GADL:	SKIPN JOB+P2PID		;IS IT THE NULL JOB
	CONSZ PI,77400		;YES, ARE WE IN PROGRESS AT ALL
	JRST P2GBAD		;NOT NULL JOB, OR IN PROGRESS SOMEWHERE
	HRRZ TAC,TAC		;GET ADDRESS OF REQUEST
	CAIGE TAC,40000		;NULL JOB IS ADDRESS LIMITED TO 16K
	JRST P2GBAD		;WELL, THAT WASN'T IT
	POP P,TAC
	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /ADDRESS LIMIT VIOLATION FROM NULL JOB
/
	PUSHJ P,DISFLU
	PUSHJ P,WDDTCA
	POPACS
	EXCH P,P2GPDL
	JRST NULP2		;START UP THE NULL JOB AGAIN
;KLPFTR - KL10 PAGE TRAPS
IFKL10,<
KLPFT0:	MOVEM TAC,PFTAC
	LDB TAC,[POINT 5,KLUPT+KLPFW,5]	;GET FAILURE TYPE
	CAIE TAC,36			;IS IT AR PAR ERROR
	CAIN TAC,37			; OR ARX?
	JRST KLPAR0
	MOVE TAC,PFTAC
	JRST KLPFT1

↑KLPFTR:CONSO PI,77400
	JRST KLPFT1
	CONSO PI,PION			;SKIP IF PI SYSTEM IS ON
	JRST KLPFT0
	CONO PI,PIOFF
	MOVEM TAC,PFTAC
	LDB TAC,[POINT 5,KLUPT+KLPFW,5]	;GET FAILURE TYPE
	CAIE TAC,36			;IS IT AR PAR ERROR
	CAIN TAC,37			; OR ARX?
	JRST KLPAR
	MOVE TAC,PFTAC
	CONO PI,PION
KLPFT1:	EXCH P,PAGPDL
	CAME P,[-PAGPLN,,PAGPD-1]
	JRST 4,.			;HALT INSTEAD OF TRYING RECURSION
	PUSH P,KLUPT+KLPFW
	PUSH P,KLUPT+KLPFPC
	POP P,SVPFPC
	POP P,SVPFW
	PUSH P,TAC
	LDB TAC,[POINT 5,KLUPT+KLPFW,5]	;GET FAILURE TYPE
	CAIE TAC,36
	CAIN TAC,37
	JRST PFPAR			;AR/ARX PARITY ERROR
	CAIN TAC,23			;IS IT ADDRESS BREAK?
	JRST KLADRB			;YES. (SEE KLSER)
	SKIPL TAC,KLUPT+KLPFW		;GET PAGE FAIL WORD
	JRST EPF			;EXEC MODE REFERENCE FAILED
	LDB TAC,[POINT 5,TAC,5]
	CAIN TAC,21			;USER PROPRIETARY VIOLATION
	JRST PFPUB
	CAIE TAC,24			;ILLEGAL WRITE
	CAIN TAC,30			;SECTION NO ACCESS
	JRST DOMPV
	CAIE TAC,33			;PAGE NO ACCESS?
	JRST HPF			;HARDWARE PAGE FAIL
DOMPV:	CONSZ PI,77400			;SKIP UNLESS IN PROGRESS
	JRST PIPF			;PAGE FAIL IN BAD PI CHANNEL
	MOVE TAC,KLUPT+KLPFPC
	TLNE TAC,USRMOD			;SKIP UNLESS FAILING PC IS IN USER MODE
	JRST DOMPV1
	SKIPN TAC,PFIOEF		;SKIP IF DOING XCTR AT PFIOUU
	JRST DOMPV2			;NOT
	SETZM PFIOEF			;WAS A REAL PAGE FAULT ON EFF ADR CALC
	MOVEM TAC,KLUPT+KLPFPC		;PUT BACK PREVIOUS FAULT PC (USER MODE PC)
	DATAI KLPAG,TAC			;GET AC CONTEXT
	TLNE TAC,001000			;SHOULD BE EXEC (0)
	JRST DOMPV2
	POP P,TAC
	EXCH P,PAGPDL
	DATAO KLPAG,[401000,,0]		;BACK TO USER AC CONTEXT
	EXCH P,PAGPDL
	PUSH P,TAC
	JRST DOMPV2			;AND TAKE A PAGE FAULT

DOMPV1:	TLNE TAC,4000			;SKIP UNLESS FAILING PC IS IN IOT USER MODE
	JRST DOMPV2
	TLZ TAC,17
	XOR TAC,KLUPT+KLPFW
	TDNN TAC,[17,,-1]		;SKIP IF PF PC IS DIFFERENT THAN LOSING ADDR
	JRST DOMPV2			;PAGE FAULT WAS FROM INSTRUCTION FETCH
	XCTR XLB,[LDB TAC,[POINT 9,@KLUPT+KLPFPC,8]]	;GET TOP 9 BITS AT THAT PC
	CAIN TAC,<XCT>⊗-=27
	JRST PFIOUU			;IT'S AN EXECUTE
	TRC TAC,700
	TRCN TAC,700			;SKIP IF NOT AN I/O INSTRUCTION
	JRST PFIOUU			;REALLY AN I/O UUO (MAYBE)
DOMPV2:	MOVEI TAC,ILM			;SIMULATE MPV BIT IN KA10 STYLE CONI
DOMPV3:	IORM TAC,KLECON			;TURN ON IN KL10 ERROR CONI BITS
	POP P,TAC
	EXCH P,PAGPDL
	JRST KLEINT

;GET HERE IF THE PAGE FAULT WAS IN USER MODE, NOT IOT USER MODE.
PFIOUU:	POP P,TAC
	EXCH P,PAGPDL			;ALL USER'S ACS ARE NOW BACK
	DATAI KLPAG,KLUPT+426		;STORE PROCESS CONTEXT FOR MUUO TRAP
	DATAO KLPAG,[400100,,0]		;GET AC BLOCK 0, PREV 1
	MOVE P,PAGPDL			;GET A STACK
	MOVE TAC,KLUPT+KLPFPC		;USER ADDRESS OF FAILING INSTRUCTION
	MOVEM TAC,PFIOEF		;FLAG THAT WE MAY GET PF ON EFF ADR CALC
	MOVE TAC1,TAC
	HRRI TAC1,1(TAC1)		;SIMULATE PC THAT WOULD BE STORED ON MUUO
	MOVEM TAC1,KLUPT+425		;STORE AS MUUO PC WORD
PFIOU2:	PUSHJ P,PFIFET			;COMPUTE INSTRUCTION AT (TAC) INTO TAC1
	LDB AC1,[POINT 9,TAC1,8]	;GET OPCODE
	CAIN AC1,<XCT>⊗-=27
	JRST PFIOU1
	TRC AC1,700
	TRNE AC1,700			;SKIP IF IT'S AN I/O INSTRUCTION
	JRST PFIOU3			;NOT XCT AND NOT I/O INSTRUCTION
	MOVEM TAC1,KLUPT+424		;STORE MUUO WORD
	SETZM PFIOEF
	JRST 2,@KLUPT+434		;SIMULATE CONCEALED NO TRAP MUUO

PFIOU1:	MOVE TAC,TAC1			;COPY INSTR TO TAC (RH GETS EFF ADR OF XCT)
	JRST PFIOU2

PFIOU3:	SETZM PFIOEF
	DATAO KLPAG,[401000,,0]		;BACK TO AC BLOCK 1
	EXCH P,PAGPDL
	PUSH P,TAC
	JRST DOMPV2			;BACK WHERE WE CAME FROM

;ROUTINE TO COMPUTE INSTRUCTION IN MUUO STORING FORMAT.  ASSUMES TAC HAS USER
;ADDRESS OF THE INTRUCTION.  RETURNS RESULT IN TAC1
PFIFET:	HRLI TAC,(<MOVEI TAC1,@0>)	;MAKE A <MOVEI TAC1,@ADDRESS OF INSTR>
	XCTR XE,TAC			;RELOCATE ON @ AND XR
	XCTR XR,[HLL TAC1,(TAC)]	;GET OPCODE AND AC FIELD
	TLZ TAC1,37			;CLEAR @ AND XR BITS
	POPJ P,

PFPUB:	MOVE TAC,KLUPT+KLPFPC
	TLNN TAC,USRMOD
	JRST PFPUBE			;FROM AN XCTR, SOMEONE HAS SET PCP OR PUBLIC
	MOVSI TAC,PCPUBL
	JRST DOMPV3

PFPUBE:	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /Exec mode proprietary violation, check PCP and PUBLIC bits./
	JRST PFCOM

EPF:	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /Exec mode page failure /
PFCOM:	PUSHJ P,DISMES
	ASCIZ /
Page failure word = /
	MOVE TAC,KLUPT+KLPFW
	PUSHJ P,DISOCT
	PUSHJ P,DISMES
	ASCIZ /    Trap PC = /
	MOVE TAC,KLUPT+KLPFPC
	PUSHJ P,DISOCT
	PUSHJ P,DISMES
	ASCIZ /
PI CONI = /
	CONI PI,TAC
	PUSHJ P,DISOCT
	PUSHJ P,DISCRLF
	PUSHJ P,DISFLU
	POPACS
	POP P,TAC
	PUSHJ P,DDTCALL
EPFXIT:	EXCH P,PAGPDL			;YOU PROBABLY SHOULDN'T CONTINUE...
	JRST 2,@KLUPT+KLPFPC

HPF:	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /Hardware page fail/
	JRST PFCOM

PIPF:	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /Page fail, PI in progress/
	JRST PFCOM
;KL10 AR/ARX PARITY ERROR PAGE FAULTS

PFPAR:	POP P,TAC
	EXCH P,PAGPDL
	JRST KLPAR1

KLPAR0:	MOVE TAC,PFTAC
	JRST KLPAR1

KLPAR:	MOVE TAC,PFTAC
	CONO PI,PION
KLPAR1:	CONSZ PI,70000			;SKIP IF WE CAN GET TO CHANNEL 3
	JRST KLPAR2
	SETOM PFPARF			;TELL CH3 WHY WE'RE COMING
	CONO PI,4000+1⊗<7-APRCHN>	;INITIATE INTO CHANNEL 3
	CONO PI,0			;WAIT UNTIL GET INTO CH3
	HALT .

KLPAR2:	CONO PI,PIOFF
	EXCH P,ETRPDL
	PUSHACS
	PUSHJ P,DISMES
	ASCIZ \AR/ARX PARITY ERROR FAULT -  PI IN PROGRESS CHANNELS 1-3
\
	PUSHJ P,DISFLU
	POPACS
	PUSHJ P,DDTCAL
	EXCH P,ETRPDL
	CONO PI,PION
	JRST 2,@KLUPT+KLPFPC

>;IFKL10
;PAGSET, PAGSEN, PAGSE1, P2GSE1

↑PAGSET:JUMPE J,PAGSNL
	SKIPN TAC,JBTMAP(J)
	JRST PAGJM0		;ERROR- JBTMAP IS ZERO
	LSH TAC,=18		;PAGE NUMBER OF PAGE MAP INTO LEFT HALF.
	JUMPN PID,P2GSET
	HRRI TAC,EXPGT⊗-9	;MBR
PAGSEN:	MOVEM TAC,PAGREG
PAGSE1:	PUSH P,TAC
	PUSH P,TAC1
	HRRZ TAC,PAGREG
	HLRE TAC1,PAGREG
	BLKI KLPAG,TAC		;SET EXPGT AND USPGT POINTERS IN AC BLOCK 6
	CONO KLPAG,@KLPCON	;FLUSH OLD ARS
	POP P,TAC1
	JRST TPOPJ

PAGSNL:	JUMPN PID,P2GSNL
	MOVE TAC,[400000,,EXPGT⊗-9]	;SIGN BIT MEANS THERE IS NO USER PAGE TABLE
	JRST PAGSEN	

P2GSET:	HRRI TAC,PSB⊗-9
P2GSEN:	MOVEM TAC,P2PAG
	MOVSI TAC,700000
	IORI TAC,(J)		;LET'S SEE THE JOB NUMBER IN THE CST LIGHTS IN PAGER
	MOVEM TAC,P2PAG1	;SET AGER TO 700
P2GSE1:	CONO PAG,0		;CAUSE PAGER TO RELOAD MAIN REGISTERS
	CONO PAG,3		;CLEAR ARS MAPPING USER MODE PAGES
	CONO PAG,7		;TURN ON MAPPING FOR USER AND ALL EXEC ADDRESSES
	DATAO APR,[776000,,0]	;SET PROT,,RELOC TO ∞,,0
	POPJ P,

P2GSNL:	MOVE TAC,[BYTE (4)0 (3)7 (11)PSB⊗-9 (5)0 (2)0 (11)PSB⊗-9]	;ALR=16K
	JRST P2GSEN		;USE FIRST 32 WORDS OF PSB AS MAP FOR NULJOB

PAGJM0:	PUSHACS
	PUSHJ P,DISJOB
	PUSHJ P,DISMES
	ASCIZ / JBTMAP IS ZERO AT PAGSET.  FATAL.
/
	PUSHJ P,DISFLU
	POPACS
	PUSHJ P,DDTCALL
	JUMPN PID,PAGJ0A
	HALT AUTOLO

PAGJ0A:	JRST 4,.
;ADPEMP, ADDEMP, DELEMP, ADDEVP

;ADD A PHYSICAL PAGE TO THE EXEC MAP
;CALL:	MOVE	TAC,<PHYSICAL PAGE NUMBER>
;	MOVE	TAC1,<VIRTUAL PAGE NUMBER>
;	PUSHJ	P,ADDEMP		;CLOBBERS ONLY TAC
;	<RETURN>
;IF ERRORS OCCUR, YOU WIND UP IN DDT

IFN FTEXPG,<

;SAME AS ADDEMP EXCEPT THE PAGE GETS WRITE PROTECTED AND CACHED
ADPEMP:	JUMPL	TAC1,ADDEM1	;JUMP IF PAGE NUMBER IS NEGATIVE
	CAILE	TAC1,777	;SKIP IF PAGE NUMBER IS REASONABLE
	JRST	ADDEM1		;ERROR - VIRTUAL PAGE NUMBER OUT OF BOUNDS
	JUMPL	TAC,ADDEM1	;ERROR IF PHYSICAL PAGE NUMBER IS NEGATIVE
	CAIL	TAC,PHYMEM*2	;SKIP IF PHYSICAL PAGE IS OK
	JRST	ADDEM1
NOKL10,<HRLI	TAC,120040	;READ-EXECUTE AND ACCESS PERMISSION  >;NOKL10
IFKL10,<HRLI	TAC,130040	;SAME AS ABOVE BUT WITH CACHE BIT ON >;IFKL10
	JRST	ADDEMX


↑ADDEVP:MOVE	TAC,TAC1	;USE THE SAME PHYSICAL PAGE AS VIRTUAL PAGE
↑ADDEMP:JUMPL	TAC1,ADDEM1	;JUMP IF PAGE NUMBER IS NEGATIVE
	CAILE	TAC1,777	;SKIP IF PAGE NUMBER IS REASONABLE
	JRST	ADDEM1		;ERROR - VIRTUAL PAGE NUMBER OUT OF BOUNDS
	JUMPL	TAC,ADDEM1	;ERROR IF PHYSICAL PAGE NUMBER IS NEGATIVE
	CAIL	TAC,PHYMEM*2	;SKIP IF PHYSICAL PAGE IS OK
	JRST	ADDEM1
	HRLI	TAC,160040	;READ-WRITE-EXECUTE AND ACCESS PERMISSION
ADDEMX:	PUSH	P,AC1
	MOVEI	AC1,EXPGT(TAC1)	;ADDRESS OF THE EXPGT ENTRY FOR THIS PAGE.
	SKIPE	(AC1)		;SKIP IF THERE'S NO OLD ENTRY.
	CAMN	TAC,(AC1)	;THERE IS AN OLD ENTRY.  SKIP IF DIFFERENT FROM NEW
	JRST	ADDEM0		;WINNING.
	PUSHACS	
	PUSHJ	P,DISMES
	ASCIZ	/CONFLICTING ASSIGNMENT AT ADDEMP
/
	PUSHJ	P,DISFLU
	POPACS
	PUSHJ	P,WDDTCAL		;IF YOU CONTINUE IT CLOBBERS IT ANYWAY
ADDEM0:	MOVEM	TAC,(AC1)
	POP	P,AC1
	POPJ	P,

ADDEM1:	PUSHACS
	PUSHJ	P,DISMES
	ASCIZ	/FATAL - ILLEGAL ARGUMENTS AT ADDEMP OR DELEMP
/
	PUSHJ	P,DISFLU
	POPACS
	PUSHJ	P,DDTCAL
	HALT	AUTOLO

;DELETE A VIRTUAL PAGE FROM THE EXEC MAP
;CALL:	MOVE TAC1,<VIRTUAL PAGE NUMBER>
;	PUSHJ P,DELEMP
;	<RETURN>
;IF ERRORS OCCUR, YOU WIND UP IN DDT

↑DELEMP:JUMPL TAC1,ADDEM1	;ERROR IF PAGE NUMBER IS NEGATIVE
	CAILE TAC1,777		;SKIP IF PAGE NUMBER IS REASONABLE
	JRST ADDEM1		;ERROR - VIRTUAL PAGE NUMBER OUT OF BOUNDS
	PUSH P,AC1
	MOVEI AC1,EXPGT(TAC1)	;ADDRESS OF THE EXPGT ENTRY FOR THIS PAGE.
	SETZM (AC1)		;ZERO THE ENTRY IN THE EXPGT
	JUMPN PID,DELEM1
	MOVEI AC1,(TAC1)
	LSH AC1,9		;CONVERT VIRTUAL PAGE TO ADDRESS
	BLKO KLPAG,(AC1)
	POP P,AC1
	POPJ P,

DELEM1:	CONO PAG,1		;CLEAR ARS MAPPING EXEC PAGES
	POP P,AC1
	POPJ P,
>;FTEXPG
;PAGINI - INITIALIZE THE EXEC PAGE TABLE, PSB, AND WHATNOT

IFE FTEXPG,<	PAGINI:	POPJ	P,	>

IFN FTEXPG,<

↑PAGINI:SETZM	EXPGT
	MOVE	TAC,[EXPGT,,EXPGT+1]
IFKL10,<
	BLT TAC,EXPGT+777
>;IFKL10
NOKL10,<
	BLT	TAC,EXPGT+577
	MOVSI	TAC,700400	;SETUP CST
	MOVEM	TAC,CST
	MOVE	TAC,[CST,,CST+1]
	BLT	TAC,CST+2*PHYMEM-1
	SETZM	PSB
	MOVE	TAC,[PSB,,PSB+1]
	BLT	TAC,PSB+777
>;NOKL10

	MOVEI	TAC1,0		;INCLUDE LOW EXEC IN PHYSICAL MAP
	MOVEI	AC3,0		;COUNT ADDRESSES
PGINI1:	MOVEI	AC1,ADPEMP	;ASSUME WRITE PROTECT
	CAIL	AC3,CHKBEG
	CAIL	AC3,CHKEND&777000
	MOVEI	AC1,ADDEMP	;WRITE ENABLE
	MOVEI	TAC,(TAC1)
	PUSHJ	P,(AC1)		;ADD PHYSICAL PAGE TO MAP (STRAIGHT THROUGH)
	ADDI	AC3,1000
	CAMGE	AC3,SYSTOP	;DONE YET?
	AOJA	TAC1,PGINI1	;NO.  LOOP.

IFN FTHSYS,<
	MOVEI	AC2,0+(HIEND-400000)⊗-=9
	MOVE	TAC,FHIPAG			;FIRST PHY. PAGE OF HISYS
	MOVEI	TAC1,400			;FIRST VIR. PAGE OF HISYS
PGINI2:	PUSHJ	P,ADPEMP			;CLOBBERS ONLY LH OF TAC
	ADDI	TAC1,1
	MOVEI	TAC,1(TAC)
	SOJG	AC2,PGINI2
>

;(NOTE - FREE STORAGE SYSTEM IS RESPONSIBLE FOR IT'S OWN MAP SETUP)

	POPJ	P,

>;FTEXPG

>;FTPAGER

;MAPSET, APRMAP, POPMAP, ACTOSH, SHTOAC, PSHMAP
;CALL:	MOVE	J,<JOB NUMBER>		;CLOBBERS NO ACS
;	PUSHJ	P,MAPSET
;	<RETURN HERE WITH OLD MAP PUSHED, AND MAP SETUP FOR NEW JOB>
;
;ONCE YOU'VE CALLED MAPSET, THE NEXT POPJ P, AT THE STACK LEVEL RETURNED
;BY MAPSET, WILL RESTORE THE STATE OF THE MAP, AND POPJ ONE LEVEL ABOVE
;WHERE YOU WERE WHEN YOU CALLED MAPSET.  I.E., DO A POPJ TO RESTORE THE
;MAP AND RETURN TO WHOEVER CALLED YOU (WHERE YOU=THE CALLER OF MAPSET)
;ALSO, JRST CPOPJ1 FROM THE CALLER OF MAPSET WILL WORK RIGHT.


IFN FTPAGER,<SDEPTH←←4>
IFE FTPAGER,<SDEPTH←←1>


↑MAPSET:PUSHJ P,PSHMAP			;SAVE STATE OF MAP
	PUSHJ P,APRMAP			;NOW SETUP THE MAP
	PUSHJ P,@-SDEPTH(P)		;RETURN TO CALLER OF MAPSET, WHO POPJS 
	SOS -1-SDEPTH(P)		;(AVOID SKIP RETURN)   BACK HERE TO RESTORE
	PUSHJ P,POPMAP			;POP MAP AND AC CONTEXT BACK
	SUB P,[1,,1]			;FLUSH ORIGINAL CALL TO MAPSET
	JRST CPOPJ1			;RETURN TO CALLER OF MAPSET'S CALLER.

IFKL10,<
;COPY AC BLOCK 1 TO SHADOW MEMORY OF JOB WHOSE MAP IS CURRENTLY SET UP ONLY
;IF NOT PI IN PROGRESS ON CHANNELS 3 THROUGH 6
ACTOSH:	SKIPL PAGREG			;SKIP IF NO USER MAP (NULL JOB)
	CONSZ PI,17000			;IN PROG ON 3-6
	POPJ P,				;YES, WON'T TRY TO REFERENCE ACS
	PUSH P,TAC
	HLRZ TAC,PAGREG
	TRNE TAC,200000			;SKIP UNLESS SUPRESS ACTOSH (SET BY SPWSER)
	JRST TPOPJ
	PUSH P,TAC1
	LSH TAC,9
	LDB TAC,[POINT 13,(TAC),35]	;DO IT THIS WAY, MAP DOESN'T REALLY WORK
	MOVEI TAC1,MAPEXP
	PUSHJ P,ADDEMP			;MAKE EXEC PAGE MAPEXP POINT AT SHADOW
	MOVEI TAC,MAPEXP⊗9
	XCTR XBLTR,[BLT TAC,MAPEXP⊗9+17]	;COPY AC BLK 1 TO HIS SHADOW ACS
	PUSHJ P,DELEMP			;FLUSH THAT PAGE
	POP P,TAC1
	JRST TPOPJ

;COPY SHADOW MEMORY OF JOB WHOSE MAP IS CURRENTLY SET UP TO AC BLOCK 1 ONLY
;IF NOT PI IN PROGRESS ON CHANNELS 3 THROUGH 6
SHTOAC:	SKIPL PAGREG			;SKIP IF NO USER MAP (NULL JOB)
	CONSZ PI,17000			;IN PROG ON 3-6
	POPJ P,				;YES.
	PUSH P,TAC
	PUSH P,TAC1
	HLRZ TAC,PAGREG
	LSH TAC,9
	LDB TAC,[POINT 13,(TAC),35]	;DO IT THIS WAY, MAP DOESN'T REALLY WORK
	MOVEI TAC1,MAPEXP
	PUSHJ P,ADDEMP			;MAKE EXEC PAGE MAPEXP POINT AT SHADOW
	MOVSI TAC,MAPEXP⊗9
	XCTR XBLTW,[BLT TAC,17]		;COPY NEW SHADOW ACS TO AC BLOCK 1
	PUSHJ P,DELEMP			;FLUSH THAT PAGE
	POP P,TAC1
	JRST TPOPJ
>;IFKL10

↑PSHMAP:
IFN SDEPTH-1,<
	ADD P,[SDEPTH-1,,SDEPTH-1]
>
	PUSH P,-SDEPTH+1(P)	;SAVE RETURN WORD FURTHER UP THE STACK
	PUSH P,TAC
	MOVEI TAC,-SDEPTH-2(P)	;POINTER TO ONE BELOW FIRST STACK ENTRY
IFE FTPAGER,<
	PUSH TAC,LASTPR+P1PID
>;IFE FTPAGER
IFN FTPAGER,<
	JUMPN PID,PSHMP1
	PUSH TAC,PAGREG
	PUSH P,TAC1
	DATAI KLPAG,TAC1
	TLZ TAC1,300000
	TLO TAC1,400000
	PUSH TAC,TAC1
	POP P,TAC1
	PUSH TAC,KLUPT+KLPFW
	PUSH TAC,KLUPT+KLPFPC
>;FTPAGER
PSHMP2:	POP P,TAC
	POPJ P,

PSHMP1:	PUSH TAC,P2PAG
	PUSH TAC,P2PAG1
	PUSH TAC,PSB+TSW
	PUSH TAC,P2GINT
	JRST PSHMP2
	

↑POPMAP:
IFN FTPAGER,<
	SKIPP2
	PUSHJ P,ACTOSH		;COPY AC BLOCK 1 TO SHADOW IF NOT PI 3-6
	EXCH TAC,-3(P)		;SAVE TAC ON STACK, GET BACK DATAI KLPAG
	JUMPN PID,POPMP1
	PUSH P,TAC1
	DATAI KLPAG,TAC1	;GET CURRENT AC CONTEXT
	XOR TAC1,TAC		;COMPARE WITH NEW
	TLNE TAC1,7000		;SKIP IF NOT CHANGING CURRENT CONTEXT
	JRST POPBUG		;HOW DO YOU EXPECT TO GET BACK?
	POP P,TAC1
	DATAO KLPAG,TAC
POPBU1:	POP P,TAC		;GET RETURN ADDRESS
	EXCH TAC,-3(P)		;SAVE AT BOTTOM OF STACK, GET PAGREG
	MOVEM TAC,PAGREG
	POP P,KLUPT+KLPFPC
	POP P,KLUPT+KLPFW
	PUSHJ P,PAGSE1
	PUSHJ P,SHTOAC		;COPY SHADOW TO AC BLOCK 1 IF NOT PI 3-6
	JRST TPOPJ
>;FTPAGER

POPMP1:	MOVEM TAC,P2PAG1
	POP P,TAC		;GET RETURN ADDRESS
	EXCH TAC,-3(P)		;SAVE AT BOTTOM OF STACK, GET PAGREG
	MOVEM TAC,P2PAG
	POP P,P2GINT
	POP P,PSB+TSW
	PUSHJ P,P2GSE1
	JRST TPOPJ

IFKL10,<
POPBUG:	POP P,TAC1
	PUSHACS
	PUSHJ P,DISMES
	ASCIZ /ATTEMPTING TO CHANGE CURRENT AC CONTEXT AT POPMAP.
PRESENT = /
	DATAI KLPAG,TAC
	PUSHJ P,DISOCT
	PUSHJ P,DISMES
	ASCIZ /   STACKED = /
	MOVE TAC,-17+TAC(P)
	PUSHJ P,DISOCT
	PUSHJ P,DISCRLF
	POPACS
	PUSHJ P,DISFLU
	PUSHJ P,WDDTCAL
	JRST POPBU1
>;IFKL10


↑APRMAP:PUSH P,TAC
IFE FTP2PAG,<
	JUMPE PID,APMAPX
	PUSHJ P,GETPR			;P2 OR OLD WAY. CALCULATE PROT-REL
	DATAO APR,TAC			;TELL APR MAP
	JRST TPOPJ	
>;NOT FTP2PAG
IFN FTP2PAG,<
	JUMPN PID,APMAP1
>;FTP2PAG
APMAPX:	MTRON (MTRMAP)
	PUSHJ P,ACTOSH			;COPY AC BLK 1 TO SHADOW IF NOT PI 3-6
APMAP3:	CONSO PI,17000			;USE WHATEVER ACS WE HAVE IF PI 3-6
	DATAO KLPAG,[400100,,0]		;SET CURRENT AC BLK TO ZERO, PREV TO 1
	JSP TAC,.+1
	TLO TAC,PCU			;ALWAYS TURN ON PCU FOR NOW
	HRRI TAC,APMAP2
	JRST 2,@TAC
APMAP2:	PUSHJ P,PAGSET
	PUSHJ P,SHTOAC			;COPY SHADOW TO AC BLK 1 IF NOT PI 3-6
APRMPZ:	POP P,TAC
	MTROFF (MTRMAP)
	POPJ P,

IFN FTP2PAG,<
APMAP1:	PUSHJ P,PAGSET			;SETUP THE MAP.
	JRST TPOPJ			;RETURN
>;FTP2PAG